From 9f6bff906b23981c3fd8b2109ab063cf4e07683b Mon Sep 17 00:00:00 2001
From: Florian Tham <tham@fidion.de>
Date: Tue, 16 Jun 2015 10:25:48 +0200
Subject: [PATCH] add sys-process/glances

---
 sys-process/glances/Manifest             |  2 +
 sys-process/glances/glances-2.4.2.ebuild | 67 ++++++++++++++++++++++++
 2 files changed, 69 insertions(+)
 create mode 100644 sys-process/glances/Manifest
 create mode 100644 sys-process/glances/glances-2.4.2.ebuild

diff --git a/sys-process/glances/Manifest b/sys-process/glances/Manifest
new file mode 100644
index 0000000..12be8c1
--- /dev/null
+++ b/sys-process/glances/Manifest
@@ -0,0 +1,2 @@
+DIST Glances-2.4.2.tar.gz 5497895 SHA256 31f1e4c2e129904a373f3b20d6800472375e415e01161168469ccebb320c9517 SHA512 ada7e2a9766dec54b26fa1fccac3b1abe6b9abcc16a96c6bb30d537370648732a99cff41c6c812908531a4995e118cb3d1127196184f40dee7a01a6a8a85d9b9 WHIRLPOOL 91cd5dfbe891c16bbbe5c6ae17500498c230d36a0795ba134a0384770cae04cbdf08b5236fd56157e438eaff17a7bd9cac3bc42bee7980239faf5c9fc18fc683
+EBUILD glances-2.4.2.ebuild 1973 SHA256 c8d273c32b9e3f4bdb336c691f40985a87c5b502cadfe4f6775def735144b129 SHA512 6332dfb7dc17cce0addeee7b060ebc9666e39f0af8f1f82733a7fabfa3019ef984f8e595f0a03dfddecd76eef279256a015e427b628f2a90c6e19c08daf2800a WHIRLPOOL 098b349247cbc6c11a85dc9275901291d52555de94f6be38940ad28e7dc537b562b550419d0be9977635caafc1c9313f59bbc629ce2a7dacea579bd7578656a8
diff --git a/sys-process/glances/glances-2.4.2.ebuild b/sys-process/glances/glances-2.4.2.ebuild
new file mode 100644
index 0000000..d8c890d
--- /dev/null
+++ b/sys-process/glances/glances-2.4.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-process/glances/glances-2.4.2.ebuild,v 1.1 2015/04/05 08:26:15 patrick Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1 linux-info
+
+MYPN=Glances
+MYP=${MYPN}-${PV}
+
+DESCRIPTION="CLI curses based monitoring tool"
+HOMEPAGE="https://github.com/nicolargo/glances"
+SRC_URI="mirror://pypi/${MYPN:0:1}/${MYPN}/${MYP}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="chart doc hddtemp snmp web"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+# There is another optional extra batinfo, absent from portage
+RDEPEND="${DEPEND}
+	>=dev-python/psutil-2.0.0[${PYTHON_USEDEP}]
+	hddtemp? ( app-admin/hddtemp )
+	snmp? ( dev-python/pysnmp[${PYTHON_USEDEP}] )
+	web? ( dev-python/bottle[${PYTHON_USEDEP}] )
+	chart? ( dev-python/matplotlib[${PYTHON_USEDEP}] )"
+
+CONFIG_CHECK="~TASK_IO_ACCOUNTING ~TASK_DELAY_ACCT ~TASKSTATS"
+
+S="${WORKDIR}/${MYP}"
+
+pkg_setup() {
+	linux-info_pkg_setup
+}
+
+python_prepare_all() {
+	sed -e "s:share/doc/glances:share/doc/${PF}:g" \
+		-e "s/'COPYING',//" \
+		-e "s:/etc:${EPREFIX}/etc:" \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	# Abnormal setup for pre-built html docs in setup.py
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	rm -rf "${D}"usr/share/doc/${PF}/{glances-doc.html,images/} || die
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "${PN} can gain additional functionality with following packages:"
+		elog "   dev-python/jinja - export statistics to HTML"
+		elog "   app-admin/hddtemp - monitor hard drive temperatures"
+		elog "   dev-python/pysnmp - enable Python SNMP library support"
+		elog "   dev-python/bottle - for Web server mode"
+		elog "   dev-python/matplotlib - for graphical / chart support"
+	fi
+}