add app-misc/anki-2.1.0_beta37

app-misc/anki/Manifest

@@ -0,0 +1,4 @@
+AUX anki-2.1.0_beta25-web-folder.patch 498 SHA256 c5faabfa528904f47c6262c7096d97be6ab8c9f4fa18f436f4124d0670b29e74 SHA512 779806afd6c0eaaac149c89bbe8da2394630aa5a611001307808339f29237b4d7f3db7e1f66241ef67e179a5ab96d64371e1b198044cd9f88389d03a5c9d8478 WHIRLPOOL eb37b16f5a983ead6d1ca2b0d2230a976176901393f2b63d5540b0d3bbd1785091249f1ae03a1aa16c497434cf315682b576e5cd19aa1eaf91c1d6e258fdcf37
+DIST anki-2.1.0_beta37.tgz 4146403 SHA256 459e01d3bc132b0cb26d846e6d48b20eb416d55d7d19b569690b4f4961021860 SHA512 77b41b3b4d02e1f31d8b93a5f78c7e1187fe9ee97d83b0bbe900ef463caa792bebe1d06d6610002c5615df69f426b61c7bbf3bc53c035ca7933f3011663bb909 WHIRLPOOL d81f3e8085b518f8dc4a17dfec6f340c930fc5b2a44177bd72340e3a7b062fea6e6b5d325900d9ebd266c8e290b803c83e56721190e2f0e2feb5de9e8fa78057
+EBUILD anki-2.1.0_beta37.ebuild 1927 SHA256 a2dae5cf057e159763d333262ecf894d700476046cafa8e0c32e18423382c2bb SHA512 4bcc148c9542d4b570369f9f4d8a2a6278885dd815af48ddb7b00ff4da03e9f998e4eb4483b506769f6df625fd547784e87e64818dfbd0dc0571b4b22bb31c80 WHIRLPOOL 8036712355fc140eef66bed9311b9ba1960cc00e4de1f40175006298fed326bfe26b1e1260cf80febae563483afeb13844028da9c6099ea07d7ddcd132cf2523
+MISC metadata.xml 619 SHA256 3087a19894696285b894be483ae3974f72eba2b194187c7763a9c7d5fbfc6ef9 SHA512 8b6656964a3c2cee9761b278839f31546a3fe2a4efd500cd015658af3502b548888e939bbeee45ead9c88632ade12c7f0ed33fcf8cdfc6d0ac91de63ac8bb351 WHIRLPOOL 897e92fd6fd8a6e3e1b5bb1cc2fb192e97e951474dd39fd75c7fd16f2fd24449be35a304b79b7aacfcfbe13de54fa831ffc89b835e1afa74e05b553e66790c1c

app-misc/anki/anki-2.1.0_beta37.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_5 python3_6 )
+PYTHON_REQ_USE="sqlite"
+
+inherit eutils python-single-r1 xdg
+
+DESCRIPTION="A spaced-repetition memory training program (flash cards)"
+HOMEPAGE="https://apps.ankiweb.net"
+
+MY_P="${P/_/}"
+SRC_URI="https://apps.ankiweb.net/downloads/beta/${MY_P}-source.tgz -> ${P}.tgz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="latex +recording +sound test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/PyQt5[gui,svg,webengine,widgets,${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.7.4[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	recording? (
+		media-sound/lame
+		>=dev-python/pyaudio-0.2.4[${PYTHON_USEDEP}]
+	)
+	sound? ( media-video/mplayer )
+	latex? (
+		app-text/texlive
+		app-text/dvipng
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.1.0_beta25-web-folder.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/updates=True/updates=False/" \
+		aqt/profiles.py || die
+}
+
+src_compile() {
+	:;
+}
+
+src_test() {
+	sed -e "s:nosetests:${EPYTHON} ${EROOT}usr/bin/nosetests:" \
+		-i tools/tests.sh || die
+	./tools/tests.sh || die
+}
+
+src_install() {
+	cp tools/runanki.system tools/anki
+	doicon ${PN}.png
+	domenu ${PN}.desktop
+	doman ${PN}.1
+
+	dodoc README.md README.development
+	python_domodule aqt anki
+	python_doscript tools/anki
+
+	# Localization files go into the anki directory:
+	python_moduleinto anki
+	python_domodule locale
+
+	# not sure if this is correct, but
+	# site-packages/aqt/mediasrv.py wants the directory
+	insinto /usr/share/anki
+	doins -r web
+}

app-misc/anki/files/anki-2.1.0_beta25-web-folder.patch

@@ -0,0 +1,11 @@
+--- anki-2.1.0beta25/aqt/mediasrv.py
++++ anki-2.1.0beta25/aqt/mediasrv.py
+@@ -13,7 +13,7 @@
+ # locate web folder in source/binary distribution
+ def _getExportFolder():
+     # running from source?
+-    srcFolder = os.path.join(os.path.dirname(__file__), "..")
++    srcFolder = os.path.join(os.path.dirname(__file__), "..", "..", "..", "..", "share", "anki")
+     webInSrcFolder = os.path.abspath(os.path.join(srcFolder, "web"))
+     if os.path.exists(webInSrcFolder):
+         return webInSrcFolder

app-misc/anki/metadata.xml

@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>patrick@gentoo.org</email>
+		<name>Patrick Lauer</name>
+	</maintainer>
+	<longdescription lang="en">
+		Anki is a program designed to help you remember facts
+		(such as words and phrases in a foreign language) as
+		quickly, easily and efficiently as possible.
+	</longdescription>
+	<use>
+		<flag name="recording">
+			Enable support for audio recording
+		</flag>
+		<flag name="sound">
+			Enable support for adding sound to cards
+		</flag>
+	</use>
+</pkgmetadata>